<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" >
    <mx:Script><![CDATA[ 
    
        import WavFile;

        private var urlldr:URLLoader;
        private var swf:Loader;

        private function wavTest():void {
            //URLLoaderでWAVファイルをByteArrayに読み込む
            urlldr = new URLLoader();
            urlldr.dataFormat = URLLoaderDataFormat.BINARY;
            urlldr.addEventListener(Event.COMPLETE, wavLoaded);
            urlldr.load(new URLRequest("test.wav"));
        }
        
        private function wavLoaded(event:Event):void {
            //読み込んだWAVファイルをSWFファイルに変換
            var wav:WavFile = new WavFile();
            if(wav.loadFromByteArray(ByteArray(URLLoader(event.target).data))){
                //LoaderでSWFファイルとして読み込む
                swf = new Loader();
                swf.loadBytes(wav.swfFile);
            }else{
                db("変換に失敗しました。");
            }
            db("------------------------------------------");
            db("ファイルサイズ：", wav.fileSize);
            db("フォーマットID：", wav.formatID);
            db("チャンネル数：", wav.channel);
            db("サンプリングレート（Hz）：", wav.rate);
            db("データ速度（Byte/sec）：", wav.bps);
            db("ブロックサイズ：", wav.blockSize);
            db("サンプルあたりのビット数：", wav.sampling);
            db("------------------------------------------");
        }

        private function db(... arguments):void {
            for(var i in arguments){
                debug.text += arguments[i].toString();
            }
            debug.text += "\n";
        }

    ]]></mx:Script>
    <mx:TextArea id="debug" width="100%" height="100%" />
    <mx:Button id="btn" label="再生" click="wavTest();"/>
</mx:Application>

package {
    public class WavFile {
        import flash.utils.*;

        //プロパティ
        public var formatID:int;
        public var channel:int;
        public var rate:uint;
        public var bps:uint;
        public var blockSize:int;
        public var sampling:int;
        public var fileSize:uint;

        public var swfFile:ByteArray;

        //WAV 定数
        private const RIFF:uint = 0x46464952;
        private const WAVE:uint = 0x45564157;
        private const FMT :uint = 0x20746D66;
        private const DATA:uint = 0x61746164;
        private const FormatID_PCM:uint = 0x0001;

        //SWF データ&定数
        private const DummyData:Array = [
            //Header
            0x46,0x57,0x53,0x06,0x00,0x00,0x00,0x00,
            0x80,0x00,0x00,0xC8,0x00,0x00,0x00,0xC8,
            0x00,0x00,0x0C,0x01,0x00,
            //SetBackgroundColor
            0x43,0x02,0xFF,0xFF,0xFF,
            //DefineShape3
            0x13,0x08,0x02,0x00,0xC0,0x00,0x00,0x00,
            0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,
            0x00,0x00,0x00,0x88,0x00,
            //PlaceObject2
            0x85,0x06,
            0x02,0x01,0x01,0x02,0x00,
            //Show Frame
            0x40,0x00
        ];

        private const SwfFileSizePosition:uint = 4;

        private var StartSoundTag:Array = [
            0xC3,0x03,0x01,0x00,0x00
        ];
        
        private var EndTag:Array = [
            0x00,0x00
        ];

        private const DefineSoundTagNo:uint = 14;
        private const DefineSoundTagHeaderLength:uint = 7;
        private const SoundFormat_PCM_Little:uint = 3;

        //ByteArrayに読み込まれたWavファイルを解析する
        public function loadFromByteArray(ba:ByteArray):Boolean {
            var tag:uint;
            var len:uint;
            var tmp:uint;
            var pos:uint;
            
            var data:ByteArray = new ByteArray();

            ba.endian = Endian.LITTLE_ENDIAN;
            ba.position = 0;

            if(ba.readUnsignedInt() != RIFF){
                trace("WAV Format Error(RIFF)");
                return false;
            }
            fileSize = ba.readUnsignedInt();
            if(ba.readUnsignedInt() != WAVE){
                trace("WAV Format Error(WAVE)");
                return false;
            }
            while(ba.bytesAvailable > 0){
                tag = ba.readUnsignedInt();
                len = ba.readUnsignedInt();
                pos = ba.position;
                switch(tag){
                case FMT:
                    //fmtチャンクの読込 
                    formatID = ba.readUnsignedShort();
                    channel = ba.readUnsignedShort();
                    rate = ba.readUnsignedInt();
                    bps = ba.readUnsignedInt();
                    blockSize = ba.readUnsignedShort();
                    sampling = ba.readUnsignedShort();
                    break;
                case DATA:
                    //dataチャンクの読込
                    data.writeBytes(ba, ba.position, len);
                    break;
                }
                ba.position = pos + len;
            }
            return writeToSwfFile(data);
        }

        //読み込んだWAVファイルのデータをSWFファイルに変換
        private function writeToSwfFile(data:ByteArray):Boolean {
            var i:int;
            var tmp:int;

            //PCM形式のみ対応
            if(formatID != FormatID_PCM){
                trace("Format ID Error");
                return false;
            }

            swfFile = new ByteArray();
            swfFile.endian = Endian.LITTLE_ENDIAN;

            //SWF Dummuy Data
            for(i = 0; i < DummyData.length; i++){
                swfFile.writeByte(DummyData[i]);
            }
            
            //SWF Define Sound Tag
            //Recordheader
            if((DefineSoundTagHeaderLength + data.length) < 0x3f){
                swfFile.writeShort((DefineSoundTagNo << 6) | (DefineSoundTagHeaderLength + data.length));
            }else{
                swfFile.writeShort((DefineSoundTagNo << 6) | 0x3f);
                swfFile.writeUnsignedInt(DefineSoundTagHeaderLength + data.length);
            }
            //Sound ID
            swfFile.writeShort(1);
            //Sound Format
            tmp = SoundFormat_PCM_Little;
            //Sound Rate
            tmp <<= 2;
            switch(int(rate/5500)){
            case 1:
                break;
            case 2:
                tmp |= 1;
                break;
            case 4:
                tmp |= 2;
                break;
            case 8:
                tmp |= 3;
                break;
            default:
                trace("Sound Rate Error");
                return false;
            }
            //Sound Size
            tmp <<= 1;
            switch(sampling){
            case 8:
                break;
            case 16:
                tmp |= 1;
                break;
            default:
                trace("Sound Size Error");
                return false;
            }
            //Sount Type
            tmp <<= 1;
            switch(channel){
            case 1:
                break;
            case 2:
                tmp |= 1;
                break;
            default:
                trace("Sound Type Error");
                return false;
            }
            swfFile.writeByte(tmp);
            //Sound Sample Count
            swfFile.writeUnsignedInt(int(data.length/blockSize));
            //Sound Data
            swfFile.writeBytes(data);

            //SWF StartSound Tag
            for(i = 0; i < StartSoundTag.length; i++){
                swfFile.writeByte(StartSoundTag[i]);
            }

            //SWF End Tag
            for(i = 0; i < EndTag.length; i++){
                swfFile.writeByte(EndTag[i]);
            }
            
            //ファイルサイズの設定
            swfFile.position = SwfFileSizePosition;
            swfFile.writeUnsignedInt(swfFile.length);
            return true;
        }
    }
}